'__________________________________________________________________ [Header] __
' Cerro Scripts:   SetAdr.vbs
'
' Copyright (c) 2006 Philipp Föckeler (www.cerrotorre.de)
'
' Dieses Skript fügt allen Benutzern innerhalb einer OU (auch in Unter-OUs)
' eine Mail-Adresse hinzu, die in der Form "Vorname.Nachname@firma.de"
' gebildet wird.
'
' Es werden nur Benutzer berücksichtigt, die die Attribute Vor- und Nachname
' gesetzt haben und die ein Postfach besitzen.
' 
' Usage:  cscript SetAdr
'
'	Auf einem Domänen-Controller der betreffenden Domäne ausführen.
'	Vorher die Variablen "ou", "user" und "passwort" anpassen !!!!
'
'______________________________________________________________________________

WScript.Echo "Set Mail Addresses     (c) 2006 CerroTorr Networking (www.cerrotorre.de)" & VbCrLf

Const ADS_PROPERTY_APPEND = 3

user = "administrator"						' Variablen zum Anpassen
passwort = "geheim"
ou = "ou=Karlsruhe,dc=cerrotorre,dc=de"				' <- in dieser OU werden die Objekte geändert !!!

								' Vorbereiten der ADO-Suche
Set ado = CreateObject("ADODB.Connection") 
ado.Provider = "ADSDSOObject"
ado.Properties("User ID") = user
ado.Properties("Password") = passwort
ado.Properties("Encrypt Password") = TRUE
ado.Open "ADS-Search"
								' Suche nach Usern mit Postfach,
								' Vor- und Nachname
filterStr = "(&(objectCategory=person)(objectClass=user)(mailNickName=*)(sn=*)(givenName=*))"
								' ADO-Suche ausführen
Set objectList = ado.Execute("<LDAP://" & ou & ">;" & _
                              filterStr & ";ADsPath;SubTree")
								' Für jeden gefundene User
While Not objectList.EOF
	userDN = objectList.Fields(0).Value			' Hole LDAP-Pfad des Objekts
	Set user = GetObject(userDN)				' Bind an Objekt
	
	WScript.Echo(user.givenName & " " & user.sn)

	newName = "smtp:" & user.givenName & "." & user.sn & "@cerrotorre.eu"  ' <======
								' HIER die Wunschadresse eintragen
								' givenName = Vorname
								' sn = Nachname
	newArray = Array(newName)
	user.PutEx ADS_PROPERTY_APPEND, "proxyAddresses", newArray 
	user.SetInfo
	
	objectList.MoveNext
WEnd